.
.  Starting Josephson Junction Cryothermometry Case Study
.
. Setting Dataplot defaults
reset data
reset plot control
erase
x3label automatic
dimension 100 variables
tic offset units screen
tic offset 5 5
title displacement 2
case asis
title case asis
label case asis
tic label case asis
character case asis all
legend case asis
.  Finished Setting Defaults
.
. Starting Step 1.1
.
skip 25
set read format 5f5.0
serial read soulen.dat y
set read format
skip 0
. Finished Step 1.1: Page Back for Output

. Starting Step 2.1
. Generate 4-plot
.
label size 6
tic label size 6
character size 4
x3label displacement 11
x3label automatic
4-plot Y
x3label
.
justification center
height 4
move 50 96
text Voltage Counts:  4-Plot
. Finished Step 2.1: Page Back for Output

. Starting Step 3.1
.
y1label y
x1label index
plot y
y1label
x1label
. Finished Step 3.1: Page Back for Output

. Starting Step 3.2
.
y1label y( i )
x1label y(i-1)
line blank
char x
lag plot y
y1label
x1label
line solid
char blank
. Finished Step 3.2: Page Back for Output

. Starting Step 3.3
.
y1label Rlc()elative uc()Flc()requency
x1label Y
let s = standard deviation y
let xmean = mean y
x2label lc()mean = ^xmean, sd = ^s
x2label displacement 14
x3label
let a = 0.3*s
let xmin = minimum y
let xmax = maximum y
class upper xmax
class lower xmin4
legend 1 Clc()lass uc()wlc()idth = ^a
relative histogram y
limits freeze
legend 1
pre-erase off
line solid
character blank
plot norpdf(x,xmean,s) for x = xmin 0.01 xmax
pre-erase on
limits
x2label
y1label
x1label
x2label displacement
. Finished Step 3.3: Page Back for Output

. Starting Step 3.4
.
y1label Dlc()ata
x1label Tlc()heoretical
char circle
char hw 1 0.75
line blank
normal probability plot y
let x1 = -2.2
let y1 = ppa0 + ppa1*x1
let n = size xplot
let xn = 2.4
let yn = ppa0 + ppa1*xn
line solid
drawdata x1 y1 xn yn
justification center
move 50 4
text Flc()itted uc()llc()ine: uc()Ilc()ntercept = ^PPA0, uc()Slc()lope = ^ppa1
y1label
x1label
. Finished Step 3.4: Page Back for Output

. Starting Step 4.1
.
summary y
. Finished Step 4.1: Page Back for Output

. Starting Step 4.2
.
let n = size y
let ymean = mean y
let ysdm = standard deviation of mean y
let idf = n - 1
.
let lclm = ymean - tppf(0.975,idf)*ysdm
let uclm = ymean + tppf(0.975,idf)*ysdm
.
let x = sequence 1 1 n
fit y x
let idf2 = n - 2
read dpst1f.dat coef coefsd
let bsd = coefsd(2)
let lclb = bsd - tppf(0.975,idf2)*bsd
let uclb = bsd + tppf(0.975,idf2)*bsd
let string idrift = NO
let atemp = lclb*uclb
if atemp < 0
  let string idrift = YES
end of if
.
. Finished Step 4.2: Page Back for Output

. Starting Step 4.3
.
let n = size y
let ysd = standard deviation y
let idf = n - 1
.
let ucls = idf*ysd*ysd/chsppf(0.025,idf)
let ucls = sqrt(ucls)
let lcls = idf*ysd*ysd/chsppf(0.975,idf)
let lcls = sqrt(lcls)
.
let x = sequence 1 1 n
let x = code4 x
levene test y x
.
. Finished Step 4.3: Page Back for Output

. Starting Step 4.4
.
runs y
.
y1label autocorrelation
x1label lag
autocorrelation plot y
y1label
x1label
let yauto = yplot(2)
let string irand = YES
let amin = maximum yplot subset tagplot = 4
let amax = maximum yplot subset tagplot = 3
if yauto < amin
  let string irand = NO
end of if
if yauto > amax
  let string irand = NO
end of if
.
. Finished Step 4.4: Page Back for Output

. Starting Step 4.5
.
set anderson darling critical value simulation
set goodness of fit fully specified off
.
let ksloc = mean y
let ksscale = sd y
normal anderson-darling goodness of fit test y
let string inormad = YES
if statval > cutoff95
  let string inormad = NO
end of if
let adstat = statval
.
let string inorm = YES
normal probability plot y
if PPCC < .987
  let string inorm = NO
end of if
.
. Finished Step 4.5: Page Back for Output

. Starting Step 4.6
.
capture grubbs.out
grubbs test y
end of capture
. Finished Step 4.6: Page Back for Output

. Starting Step 4.7
.
capture report.tex
print " "
print " "
print "Analysis for Josephson Junction Cryothermometry Data"
print " "
print "1: Sample Size                           = ^n"
print " "
print "2: Location"
print "   Mean                                  = ^ymean"
print "   Standard Deviation of Mean            = ^ysdm"
print "   95% Confidence Interval for Mean      = (^lclm,^uclm)"
print "   Drift with respect to location?       = ^idrift"
print "   (Further analysis indicates that"
print "   the drift, while statistically"
print "   significant, is not practically"
print "   significant)"
print " "
print "3: Variation"
print "   Standard Deviation                    = ^ysd"
print "   95% Confidence Interval for SD        = (^lcls,^ucls)"
print "   Drift with respect to variation?"
print "   (based on Levene's test on quarters"
print "   of the data)                          = NO"
print " "
print "4: Distribution"
print "   Normal PPCC                           = ^PPCC"
print "   Normal Anderson-Darling               = ^adstat"
print "   Data are Normal?"
print "     (as tested by Normal PPCC)          = ^inorm"
print "     (as tested by Anderson-Darling)     = ^inormad"
print " "
print "5: Randomness"
print "   Autocorrelation                       = ^yauto"
print "   Data are Random?"
print "     (as measured by autocorrelation)    = ^irand"
print " "
print "6: Statistical Control"
print "   (i.e., no drift in location or scale,"
print "   data are random, distribution is "
print "   fixed, here we are testing only for"
print "   fixed normal)"
print "   Data Set is in Statistical Control?   = NO"
print " "
print "   Note: Although we have violations of"
print "   the assumptions, they are mild enough,"
print "   and at least partially explained by the"
print "   discrete nature of the data, so we may model"
print "   the data as if it were in statistical"
print "   control"
print " "
print "7: Outliers?"
print "   (as determined by Grubbs test)        = NO"
print " "
end of capture
list report.tex
. Finished Step 4.7: Page Back for Output