CONOVER SCORE

CONOVER SCORE (LET)

Let Subcommand

Compute the Conover scores of a variable.

The Conover scores for a response variable and a group-id variable are defined as follows
\( s(j) = (R(U_{j}))^{2} \)

where

\( U(j) = |Y_{j(i)} - \bar{Y}| \)

with \( Y_{j(i)} \) denoting the j-th observation belonging to the i-th group and \( \bar{Y_{i}} \) denoting the mean of the i-th group.

Conover scores are the squared ranks of the absolute deviations from the sample group means. They are used in the SQUARED RANKS command to compare the variances of k samples.

LET <s> = CONOVER SCORES <y> <x>
                  <SUBSET/EXCEPT/FOR qualification>
where <y> is the response variable;
            <x> is the group-id variable;
            <s> is a variable where the computed Conover scores are saved; and where the <SUBSET/EXCEPT/FOR qualification> is optional.

The response variable and the group-id variable must have the same number of observations.

LET CSCORE = CONOVER SCORE Y X

Ties are assigned an average rank. For example, if the 2nd and 3rd highest values are equal, each is assigned a rank of 2.5.

None

None

SQUARED RANKS TEST	=	Perform a squared ranks test.
SIEGEL TUKEY TEST	=	Perform a Siegel-Tukey test.
KLOTZ TEST	=	Perform a Klotz test for equal variances.
MEDIAN TEST	=	Perform a median test.
ANOVA	=	Perform a fixed effects analysis of variance.
MOOD SCORES	=	Generate Mood scores.
MEDIAN SCORES	=	Generate median scores.
KLOTZ SCORES	=	Generate Klotz scores.
VAN DER WAERDEN SCORES	=	Generate Van Der Waerden scores.
SAVAGE SCORES	=	Generate Savage scores.
ANSARI BRADLEY SCORES	=	Generate Ansari Bradley scores.
PLACEMENT SCORES	=	Generate placement scores.
RANK	=	Generate the ranks of a variable.

Conover (1999), "Practical Nonparametric Statisitcs," Third Edition, Wiley, p. 401.

Nonparametric statistics

2023/06

 
. Step 1:   Define the data
.
let y1 = data 16.55 15.36 15.94 16.43 16.01
let y2 = data 16.05 15.98 16.10 15.88 15.91
let n1 = size y1
let n2 = size y2
let n = n1 + n2
.
. Step 2:   Combine into single array
.
let y tag = stack y1 y2
if n1 <= n2
   let tag = tag - 1
   let n1t = n1
else
   let tag = 0 subset tag = 2
   let n1t = n2
end of if
.
. Step 3:   Compute the Conover scores
.
let cscore = conover scores y tag
.
. Step 4:   Two-Sample Linear Rank Test
.
let temp = tag*cscore
let s = sum temp
.
let aval = sum cscore
let smean = (n1t/n)*aval
let meanrank = mean cscore
let temp = (cscore - meanrank)**2
let aval = sum temp
let svar = ((n1*n2)/(n*(n-1)))*aval
let statval = (s - smean)/sqrt(svar)
let statval = round(statval,3)
let cv = norppf(0.975)
let upplim = round(cv,2)
let lowlim = -upplim
feedback off
print "Two Sample Linear Rank Sum Test Based on Conover Scores"
print "H0: Variances are Equal"
print "Ha: Variances are Not Equal"
print "alpha: 0.05"
print "Test Statistic: ^statval"
print "Lower Critical Value: ^lowlim"
print "Upper Critical Value: ^upplim"
if statval < cv
   print "Conclusion: Accept H0"
else
   print "Conclusion: Reject H0"
end of if
    

The following output is generated

Two Sample Linear Rank Sum Test Based on Conover Scores
H0: Variances are Equal
Ha: Variances are Not Equal
alpha: 0.05
Test Statistic: -1.953
Lower Critical Value: -1.96
Upper Critical Value: 1.96
Conclusion: Accept H0