KLOTZ SCORE

KLOTZ SCORE (LET)

Let Subcommand

Compute the Klotz scores of a variable.

The Klotz scores are defined as
\( s(R_{j}) = \left( \Phi^{-1} \left( \frac{R_{j}} {n+1} \right) \right)^{2} \)

where \( R_{j} \) is the rank of the j-th observation, n is the number of observations and \( \Phi^{-1} \) is the percent point function of the normal distribution.

Klotz scores are used in the KLOTZ TEST command to test whether k samples have equal variances.

LET <s> = KLOTZ SCORE <y>             <SUBSET/EXCEPT/FOR qualification>
where <y> is the response variable;
            <s> is a variable where the computed Klotz scores are saved;
and where the <SUBSET/EXCEPT/FOR qualification> is optional.

LET KSCORE = KLOTZ SCORE Y

Ties are assigned an average rank. For example, if the 2nd and 3rd highest values are equal, each is assigned a rank of 2.5.

None

None

KLOTZ TEST	=	Perform a Klotz test for equal variances.
MEDIAN TEST	=	Perform a median test.
ANOVA	=	Perform a fixed effects analysis of variance.
MOOD SCORES	=	Generate Mood scores.
MEDIAN SCORES	=	Generate median scores.
VAN DER WAERDEN SCORES	=	Generate Van Der Waerden scores.
SAVAGE SCORES	=	Generate Savage scores.
CONOVER SCORES	=	Generate Conover scores.
ANSARI BRADLEY SCORES	=	Generate Ansari Bradley scores.
PLACEMENT SCORES	=	Generate placement scores.
RANK	=	Generate the ranks of a variable.

W. J. Conover, (1999). "Practical Nonparameteric Statistics", Third Edition, Wiley, pp. 401-402.

Nonparametric statistics

2023/06

 
. Step 1:   Define the data
.
let y1 = data 16.55 15.36 15.94 16.43 16.01
let y2 = data 16.05 15.98 16.10 15.88 15.91
let n1 = size y1
let n2 = size y2
let n = n1 + n2
.
. Step 2:   Combine into single array
.
let y tag = stack y1 y2
if n1 <= n2
   let tag = tag - 1
   let n1t = n1
else
   let tag = 0 subset tag = 2
   let n1t = n2
end of if
.
. Step 3:   Compute the Klotz scores
.
let kscore = klotz scores y
.
. Step 4:   Two-Sample Linear Rank Test
.
let temp = tag*kscore
let s = sum temp
.
let aval = sum kscore
let smean = (n1t/n)*aval
let meanrank = mean kscore
let temp = (kscore - meanrank)**2
let aval = sum temp
let svar = ((n1*n2)/(n*(n-1)))*aval
let statval = (s - smean)/sqrt(svar)
let statval = round(statval,3)
let cv = norppf(0.975)
let upplim = round(cv,2)
let lowlim = -upplim
feedback off
print "Two Sample Linear Rank Sum Test Based on Klotz Scores"
print "H0: Variances are Equal"
print "Ha: Variances are Not Equal"
print "alpha: 0.05"
print "Test Statistic: ^statval"
print "Lower Critical Value: ^lowlim"
print "Upper Critical Value: ^upplim"
if statval < cv
   print "Conclusion: Accept H0"
else
   print "Conclusion: Reject H0"
end of if
    

The following output is generated

Two Sample Linear Rank Sum Test Based on Klotz Scores
H0: Variances are Equal
Ha: Variances are Not Equal
alpha: 0.05
Test Statistic: -1.32
Lower Critical Value: -1.96
Upper Critical Value: 1.96
Conclusion: Accept H0