WEIBULL MOMENT ESTIMATES

WEIBULL MOMENT ESTIMATES (LET)

Let Subcommand

Estimate the parameters of the Weibull distribution based on summary statistics.

In most cases, we prefer to estimate the parameters of the Weibull distribution using the WEIBULL MLE Y command. However, this assumes that we have the full data set. In some cases, we may only have summary statistics available.

The input array, say X, should contain the following values:

X(1) = the sample mean
X(2) = the sample standard deviation
X(3) = the sample skewness
X(4) = the sample minimum
X(5) = the sample size


If one of the values is not available, then you can enter either CPUMIN or the statistic missing value. For example, if the skewness is not available, you can do one of the following:

PROBE CPUMIN
LET CPUMIN = PROBVAL
LET X(3) = CPUMIN


or

SET STATISTIC MISSING VALUE -9999
LET X(3) = -9999


The following output vector, say Y, is returned:

Y(1) = 3-parameter moment estimate for location
Y(2) = 3-parameter moment estimate for scale
Y(3) = 3-parameter moment estimate for shape
Y(4) = 3-parameter modified moment estimate for location
Y(5) = 3-parameter modified moment estimate for scale
Y(6) = 3-parameter modified moment estimate for shape
Y(7) = 2-parameter moment estimate for scale
Y(8) = 2-parameter moment estimate for shape


Any of these moment estimates that cannot be computed will be set to CPUMIN. This can happen if certain summary statistics are not provided or if the equation solvers are not able to find a solution.

The 3-parameter moment and modified moment estimates are computed using the codes provided on pages 341-342 of Cohen and Whitten. The 2-parameter moment estimates are computed using the equations on page 322 of Bury.

LET <y> = WEIBULL MOMENT ESTIMATES <x>
                        <SUBSET/EXCEPT/FOR qualification>
where <x> is the variable containing the summary statistics;
            <y> is a variable containing the Weibull moment estimates;
and where the <SUBSET/EXCEPT/FOR qualification> is optional and rarely used for this command.

LET Y = WEIBULL MOMENT ESTIMATES X

None

None

Cohen and Whitten (19xx), "Parameter Estimation in Reliability and Life Span Models", Marcel Dekker, p. 31 and pp. 341-344.

Bury (1999), "Statistical Distributions in Engineering", Cambridge University Press, Chapter 17.

MAXIMUM LIKELIHOOD	= Perform maximum likelihood estimation for various distributions.
BEST DIST FIT	= Perform a best distributional fit analysis.
PPCC PLOT	= Generate a probability plot correlation coefficient plot.
PROBABILITY PLOT	= Generate a probability plot.

Reliability

2012/6

 
SKIP 25
READ WEIBBURY.DAT Y
.
.  COMPUTE SUMMARY STATISTICS
.
LET YMEAN = MEAN Y
LET YSD   = SD   Y
LET YMIN  = MINI Y
LET YSKEW = SKEW Y
LET N     = SIZE Y
LET Z     = COMBINE YMEAN YSD YMIN YSKEW N
.
.  COMPUTE WEIBULL PARAMETER ESTIMATES
.
LET X = WEIBULL MOMENT ESTIMATES Z
LET LOCMOM   = X(1)
LET SCALEMOM = X(2)
LET SHAPEMOM = X(3)
LET LOCMMOM  = X(4)
LET SCALMMOM = X(5)
LET SHAPMMOM = X(6)
LET SCAL2MOM = X(7)
LET SHAP2MOM = X(8)
.
.  NOW PRINT RESULTS
.
SET WRITE DECIMALS 4
FEEDBACK OFF
WRITE "WEIBULL PARAMETER ESTIMATES FROM SUMMARY DATA"
WRITE " "
WRITE " "
WRITE "SUMMARY STATISTICS:"
WRITE "SAMPLE MEAN:         ^YMEAN"
WRITE "SAMPLE SD:           ^YSD"
WRITE "SAMPLE SKEWNESS:     ^YSKEW"
WRITE "SAMPLE MINIMUM:      ^YMIN"
WRITE "SAMPLE SIZE:         ^N"
WRITE " "
WRITE " "
IF SCALEMOM > 0
   WRITE "3-PARAMETER WEIBULL MOMENT ESTIMATES:"
   WRITE "LOCATION:            ^LOCMOM"
   WRITE "SCALE:               ^SCALEMOM"
   WRITE "SHAPE:               ^SHAPEMOM"
   WRITE " "
   WRITE " "
END OF IF
IF SCALMMOM > 0
   WRITE "3-PARAMETER WEIBULL MODIFIED MOMENT ESTIMATES:"
   WRITE "LOCATION:            ^LOCMMOM"
   WRITE "SCALE:               ^SCALMMOM"
   WRITE "SHAPE:               ^SHAPMMOM"
   WRITE " "
   WRITE " "
END OF IF
IF SCAL2MOM > 0
   WRITE "2-PARAMETER WEIBULL MOMENT ESTIMATES:"
   WRITE "SCALE:               ^SCAL2MOM"
   WRITE "SHAPE:               ^SHAP2MOM"
END OF IF
FEEDBACK ON
    

The following output is generated.

WEIBULL PARAMETER ESTIMATES FROM SUMMARY DATA
 
 
SUMMARY STATISTICS:
SAMPLE MEAN:         52.64
SAMPLE SD:           7.4851713056
SAMPLE SKEWNESS:     0.0320833036
SAMPLE MINIMUM:      40.7
SAMPLE SIZE:         20
 
 
3-PARAMETER WEIBULL MOMENT ESTIMATES:
LOCATION:            51.51579985
SCALE:               0.0775588281
SHAPE:               0.273501919
 
 
2-PARAMETER WEIBULL MOMENT ESTIMATES:
SCALE:               55.774761712
SHAPE:               8.371781427